para Genera [:marcas (filtro ["# = pri ?] pri mp contenido)]
 paracada :marcas [haz (palabra "$ mp ?) baraja valor ?]
 
 paracada :historia [
  paracada ? [
   muestrat reemplaza ?
   muestrat "| |
  ]
  (escribe)
 ]
fin

tapa "genera

para reemplaza :palabra
si miembro? (palabra "# :palabra) :marcas [devuelve decola (palabra "$ :palabra)] 
devuelve :palabra
fin

tapa "reemplaza

para baraja :l
si vacio? :l [dev []]
 
local "e
haz "e SacaAlAzar :l
dev pp :e baraja quita :e :l
fin

tapa "baraja

para guarda.texto :texto :archivo :variable
abreescritura :archivo
ponescritura :archivo
paracada :texto [escribe ?]
ponescritura []
cierra :archivo
editafichero :archivo (frase "carga.texto entrecomillas :archivo entrecomillas :variable)
fin

tapa "guarda.texto

para carga.texto :archivo :variable [:lineas []] [:linea []]
abrelectura :archivo 
ponlectura :archivo 
haz.mientras [
 haz "linea leelista 
 si (no "|| = :linea) [cola "lineas :linea]
] [no "|| = :linea]
ponlectura []
cierra :archivo 
haz :variable :lineas
fin

tapa "carga.texto

para Historia
guarda.texto :historia "historia.txt "historia
fin

tapa "Historia

para Marcas
haz "marca preguntabox [Pregunta] [¿Qué marca?]
haz "marca pri :marca
sisino (var? palabra "# :marca) [
 guarda.texto (valor palabra "# :marca) "marca.txt (palabra "# :marca)
] [
 guarda.texto [] "marca.txt (palabra "# :marca)
] 
fin

tapa "Marcas

haz "#? [[rápida] [suave] [divertida] [contenta] [amarilla] [verde] [fea]]

haz "historia [
[Mi gatita ? salió a pasear por la calle ? .]
[Se encontró con la vecina ? quien le dio leche ? .]
[Mi gatita quedó muy ? .]
]