Ejercicios de Matemáticas analizados con LogoFE

LogoFE es Logo Functional Extensions, una librería de procedimientos para ser usados con MSWLogo o con UCBLogo. El objetivo de LogoFE es proporcionar un gran "caja de herramientas" para la construcción de pequeños programas útiles o para explorar temáticas de Matemáticas, Física, Química, Estadística y otras materias de escuela, colegio y universidad.

Contenido

1. EJERCICIOS

La fuente de estos ejercicios es: Matemáticas Aplicadas a las Ciencias Sociales: Problemas Trimestre-1, Página-1.

1.1. Ejercicio 1

Compramos libros por valor de 6000 ptas.; si nos dieran tres libros más, me costarían 100 ptas. menos. ¿Cuántos libros he comprado?

Posible Solución

  1. X * P = 6000
  2. (X + 3) * (P - 100) = 6000
  1. P = 6000 / X
  2. (X + 3) * (P - 100) = 6000
  1. P = 6000 / X
  2. (X + 3) * (6000 / X - 100) = 6000
  1. P = 6000 / X
  2. (X + 3) * (6000 / X - 100) - 6000 = 0

Es probable que hayamos comprado más de un libro y quizá sean menos de 20.

muestra resuelve [invoca [[x] (:x + 3) * (6000 / :x - 100) - 6000]] [1 20]
12

Comprobemos:

muestra 6000 / 12
500

Cada uno de los 12 libros nos costó 500 ptas. Si nos dieran 15 libros, y cada uno nos costó solamente 400 ptas, el costo total fue el mismo:

muestra 15 * 400
6000

1.2. Ejercicio 2

Un país importa mensualmente 21000 vehículos de las marcas X, Y, Z, al precio de 1.2, 1.5 y 2 millones de pesetas, respectivamente. Si el total de la importación asciende a 32200 millones de ptas. y de la marca X se importa el 40% de la suma de las otras dos marcas, ¿cuántos vehículos de cada marca entran en el país?

Posible Solución

  1. X + Y + Z = 21000
  2. 1.2 X + 1.5 Y + 2 Z = 32200
  3. X = 0.4 (Y + Z)
  1. X + Y + Z = 21000
  2. 1.2 X + 1.5 Y + 2 Z = 32200
  3. X - 0.4 Y - 0.4 Z = 0
escribemat [[1 1 1 21000] [1.2 1.5 2 32200] [1 -0.4 -0.4 0]]
1 1 1 21000
1.2 1.5 2 32200
1 -0.4 -0.4 0

escribemat redmat [[1 1 1 21000] [1.2 1.5 2 32200] [1 -0.4 -0.4 0]]
1 0 0 6000
0 1 0 10000
0 0 1 5000
  1. X = 6000
  2. Y = 10000
  3. Z = 5000

Comprobemos:

muestra 6000 + 10000 + 5000
21000

muestra 1.2 * 6000 + 1.5 * 10000 + 2 * 5000
32200

muestra 10000 + 5000
15000

muestra 0.4 * 15000
6000

De las marcas Y e Z se importaron 15000 vehículos, el 40% de 15000 es 6000, que es la cantidad de vehículos importados de la marca X.

1.3. Ejercicio 3

Halla las edades de una persona, su padre y su abuelo, sabiendo que con su padre suma 55 años, con su abuelo 85, y que su padre y su abuelo suman 110 años.

Posible Solución

  1. I + P = 55
  2. I + A = 85
  3. P + A = 110
  1. 1 I + 1 P + 0 A = 55
  2. 1 I + 0 P + 1 A = 85
  3. 0 I + 1 P + 1 A = 110
escribemat [[1 1 0 55] [1 0 1 85] [0 1 1 110]]
1 1 0 55
1 0 1 85
0 1 1 110

escribemat redmat [[1 1 0 55] [1 0 1 85] [0 1 1 110]]
1 0 0 15
0 1 0 40
0 0 1 70
  1. I = 15
  2. P = 40
  3. A = 70

El Individuo tiene 15 años, el Padre tiene 40 y el Abuelo tiene 70 años.

1.4. Ejercicio 6

Resuelve las ecuaciones:

  1. x3 + x = 0
  2. x4 - x3 - 16x2 - 20x = 0
  3. x4 - 2x3 - 10x2 + 4x + 16 = 0

Posible Solución

muestra factoraPoli [1 0 1 0]
[[1 0] [1 0 1]]

muestra factoraPoli [1 -1 -16 -20]
[[1 1.99999983401322] [1 2.00000016598677] [1 -5]]

muestra factoraPoli [1 -2 -10 4 16]
[[1 1.4142135623731] [1 -1.4142135623731] [1 2] [1 -4]]
  1. (x + 0) (x2 + 1) = 0
  2. (x + 2) (x + 2) (x - 5) = 0
  3. (x + rc 2) + (x - rc 2) (x + 2) (x - 4) = 0
  1. x = 0, x = -rc -1, x = rc -1
  2. x = -2, x = -2, x = 5
  3. x = -rc 2, x = rc 2, x = -2, x = 4

1.5. Ejercicio 7a

Resuelve el sistema:

  1. x - y = 3
  2. x2 - xy = 15

Posible Solución

  1. x = 3 + y
  2. (3 + y)2 - (3 + y) y - 15 = 0

Veamos más o menos por dónde se encuentran las raíces de la segunda ecuación:

grafLineas [] recorrido [[y] (3+:y) * (3+:y) - (3+:y)*:y - 15] dominio [-10 10 50]

Imagen: logofe 05

Parece ser una recta, y lo verificamos observando que el término elevado al cuadrado se anula en la expresión. Entonces la respuesta es:

y = 2
x = 3 + 2 = 5

Verificamos que:

x - y = 5 - 2 = 3
x2 - xy = (5)(5) - (2)(5) = 25 - 10 = 15

1.6. Ejercicio 7b

Resuelve el sistema:

  1. x2 - xy = 8
  2. y2 - xy = -4

Posible Solución

Transformemos los ecuaciones para que puedan graficarse:

  1. y = (x2 - 8) / x
  2. x = (y2 + 4) / y

La primera ecuación puede graficarse como una función de x. Esta función tiene una asíntota en x = 0.

grafLineas [] recorrido [[x] (:x*:x - 8) / :x] dominio [-6 6 60]

Imagen: logofe 01

La segunda ecuación es una función de y. Esta función también tiene una asintota, en y = 0. Si consideramos el eje horizontal como el eje Y resulta:

grafLineas [] recorrido [[y] (:y*:y + 4) / :y] dominio [-6 6 60]

Imagen: logofe 02

Pero para juntar ambas gráficas convendremos en que el eje horizontal sea el eje X y el vertical sea el eje Y. Por lo que la segunda ecuación se puede graficar así:

grafLineas [] refleja recorrido [[y] (:y*:y + 4) / :y] dominio [-6 6 60]

Imagen: logofe 03

Al juntar ambas gráficas y definir adecuadamente el sector del plano cartesiano a mostrar, se puede apreciar las soluciones del sistemas de ecuaciones:

grafLineas [] frase refleja recorrido [[y] (:y*:y + 4) / :y] dominio [-6 6 60] ~
recorrido [[x] (:x*:x - 8) / :x] dominio [-6 6 60]

Imagen: logofe 04

x = -4, y = -2

x = 4, y = 2

  1. x2 - xy = 8 (4)2 - (4)(2) = (4)(4) - (4)(2) = 16 - 8 = 8
  2. y2 - xy = -4 (2)2 - (4)(2) = (2)(2) - (4)(2) = 4 - 8 = -4

1.7. Ejercicio 14

Se sabe que el peso ideal correspondiente a las alturas de los hombres se rige por una función lineal. Sabemos que a una altura de 165 cm y a una de 170 cm, corresponden los pesos ideales de 68 kg y de 72 kg., respectivamente. Obtén por interpolación la función lineal correspondiente.

¿Cuál es el peso adecuado para un hombre que mide 172 cm? ¿Y cuál es la altura ideal de un hombre que tiene un peso de 70 kg?

Posible Solución

En un plano cartesiano de alturas versus pesos los puntos [165 68], [170 72] definen una recta (un polinomio de primer grado):

muestra calzaPoli lista 1 [[165 68] [170 72]]
[0.8 -64]

muestra calzaPoli lista 1 impon "refleja [[165 68] [170 72]]
[1.25 80]
  1. p = 0.8 a - 64
  2. a = 1.25 p + 80

El peso adecuado para un hombre que mide 172 cm es 73.6 kg:

muestra evalPoli [172 [0.8 -64]]
73.6

La altura ideal de un hombre que tiene un peso de 70 kg es 167.5 cm:

muestra evalPoli [70 [1.25 80]]
167.5

1.8. Ejercicio 21

El número de turistas que visitaron España en el periodo 1970 a 1985 siguió la siguiente tendencia: año 1970 - 24.1 millones de turistas, año 1975 - 30.1 millones de turistas, año 1980 - 38,1 millones de turistas, y 1985 - 43.1 millones de turistas. a) Halla la previsión para el año 1988 a partir de la función de interpolación lineal que obtienes a partir de los datos correspondientes a 1980 y 1985. b) Realiza la misma previsión utilizando el polinomio de interpolación de 2º grado (interpolación cuadrática) utilizando la información de los últimos tres años.

Posible Solución

Esta es la lista de datos que pueden ser representados como puntos en el plano cartesiano: [[1970 24.1] [1975 30.1] [1980 38.1] [1985 43.1]]

grafLineas pp (lista "DotP: enlista dotPoligono [4 6 45]) ~
[[Xtic: 15] [XMod: [fix: 0]] [YMin: 24] [YMax: 44]] ~
trans [[1970 24.1] [1975 30.1] [1980 38.1] [1985 43.1]]

Imagen: logofe 06

Utilizando los dos últimos puntos para definir una recta determinamos que la recta tendrá la siguiente ecuación.

muestra calzaPoli lista 1 [[1980 38.1] [1985 43.1]]
[1 -1941.9]

f(x) = y = x - 1941.9

Y al evaluar la función para x = 1988, encontramos que el número de turistas proyectados para 1988 es 46.1 millones:

muestra evalPoli lista 1988 [1 -1941.9]
46.0999999999999

Utilizando los tres últimos años determinamos una parábola así:

muestra calzaPoli lista 2 [[1975 30.1] [1980 38.1] [1985 43.1]]
[-0.0599992500093749 238.897030037125 -237756.959749253]

f(x) = y = -0.0599992500093749 x2 + 238.897030037125 x - 237756.959749253

Y al evaluar la función para x = 1988, encontramos que el número de turistas proyectados para 1988 es 44.7 millones:

muestra evalPoli lista 1988 [-0.0599992500093749 238.897030037125 -237756.959749253]
44.6600355005357

Esto último podría graficarse así:

haz "coefs calzaPoli lista 2 [[1975 30.1] [1980 38.1] [1985 43.1]]
haz "forma pp (lista "PalL: pp [] :graf.PalL:) ~
pp (lista "DotP: (lista dotPoligono [4 6 45] [])) [[Xtic: 15] [XMod: [fix: 0]]]

grafLineas :forma fr trans [[1975 30.1] [1980 38.1] [1985 43.1] [1988 44.7]] ~
recorrido [evalPoli lista ? :coefs] dominio [1974 1989 30]

Imagen: logofe 07

1.9. Ejercicio 25

Resuelve la siguiente ecuación:

Imagen: logofe 08

Posible Solución

Gráfiquemos ambos lados de la ecuación como si fuesen funciones. Pero primero averiguemos dónde se hacen cero las expresiones debajo de los radicales:

muestra resuelve [invoca [[x] 2 * :x + 15]] [-10 10]
-7.5

muestra resuelve [invoca [[x] :x + 4]] [-10 10]
-4

grafLineas [] fr recorrido [[x] 2 + rc :x + 4] dominio [-4 10 50] ~
recorrido [[x] rc 2 * :x + 15] dominio [-7.5 10 50]

Imagen: logofe 09

Una vez determinada la ubicación aproximada de las soluciones podemos hacer mejores aproximaciones:

muestra resuelve [invoca [[x] (rc 2 * :x + 15) - (2 + rc :x + 4)]] [-4 0]
-3

muestra resuelve [invoca [[x] (rc 2 * :x + 15) - (2 + rc :x + 4)]] [0 10]
4.99999999999997

1.10. Ejercicio 28

Resuelve la siguiente ecuación: 2x4 - 5x3 +5x - 2 = 0

Posible Solución

muestra factoraPoli [2 -5 0 5 -2]
[[1 -0.5] [1 -1] [1 1] [2 -4]]

muestra impon "cuadRaices factoraPoli [2 -5 0 5 -2]
[[0.5] [1] [-1] [2]]

Así que todas son raíces reales: x = 0.5, x = 1, x = -1, x = 2

1.11. Ejercicio 29

Expresa el área de un triángulo rectángulo de perímetro 20 cm. en función de la longitud de la base. ¿Para qué longitud de la base el área será máxima?

Posible Solución

El perímetro de un triángulo rectángulo debe ser:

funciona "hipotenusa [aplica [[c1 c2] rc :c1 * :c1 + :c2 * :c2]]

muestra hipotenusa [3 4]
5

funciona "perimetro [aplica [[c1 c2] :c1 + :c2 + hipotenusa lista :c1 :c2]]

muestra perimetro [3 4]
12

Si el perímetro del triángulo debe ser 20 cm. entonces si damos algún valor a un cateto (a la base) el otro cateto no podrá tener cualquier valor, sino que deberá tener un valor fijo.

funciona "otro.cateto [invoca [[c1] resuelve [20 - perimetro lista :c1] [0 20]]]

muestra otro.cateto 3
8.23529411764706

muestra hipotenusa [3 8.23529411764706]
8.76470588235294

muestra suma [3 8.23529411764706 8.76470588235294]
20

El área de un triángulo es: base * altura / 2. Y en el caso de un triángulo rectángulo la base podría ser el un cateto y la altura el otro:

funciona "area [aplica [[base altura] :base * :altura / 2]]

muestra area [3 4]
6

Finalmente grafiquemos el área del triángulo en función de la longitud de la base. Esta longitud no podrá ser menor a 0, ni tampoco mayor a 10 (porque en el caso extremo de que sea 10, la hipotenusa deberá ser igualmente 10 para que dicho "triángulo" tenga perímetro 20).

graflineas [] recorrido [area lista ? otro.cateto ?] dominio [0 10 20]

Imagen: logofe 10

La longitud de la base para la que el área máxima del tríangulo parece estar cerca de 6. Pero en 6 el área ya se está reduciendo (ya que la taza de variación instantánea, la derivada, es negativa en 6).

muestra deriva [invoca [area lista ? otro.cateto ?]] lista 1 6
-0.204081958038671

Pero la solución está entre 5 y 7:

muestra resuelve [deriva [invoca [area lista ? otro.cateto ?]] lista 1] [5 7]
5.85786415529818

muestra otro.cateto 5.85786415529818
5.85786459723991

muestra hipotenusa [5.85786459723991 5.85786415529818]
8.2842712474619

muestra suma [5.85786459723991 5.85786415529818 8.2842712474619]
20

muestra area lista 5.85786415529818 otro.cateto 5.85786415529818
17.157287525381

2. Licencia

Este es un documento libre.

Autor: Daniel Ajoy

Creative Commons License
Esta obra está licenciada bajo una Licencia Creative Commons Atribución-Compartir Obras Derivadas Igual 2.5 España.

3. Preguntas, Dudas, Comentarios, Peticiones

Nombre:
Ciudad y País:
Email:
 

4. Enlaces

Página Principal

Ejercicios de Plano Cartesiano


Generado con PureJoy.
Fecha: 15:31 - Jul 06, 2017